Lucee Developer

I recently had to dive into errors from one of our most busy web applications. The errors came from SQL Server, saying "Transaction (Process ID 51) was deadlocked on lock resources with another process and has been chosen as the deadlock victim. Rerun the transaction.".

This error comes from SQL Server, and more or less says "I could not execute your query, because it got in the way of another query". Veeery simply said, I know.

First thing I did, was asking the Railo team whether we could create a new option in the datasource screen "retry deadlocked query", with a number indicating the maximum number of retries. Initial reactions were positive, so I added a feature request into the Railo JIRA.

But, problem still remains for now. In my situation, it was always a SELECT query which was chosen as the deadlock victim. Now, I did a lot of googling and reading about preventing or circumventing this problem, and the most common answer was "use Read Uncommitted with your select statements, if you don't mind dirty reads". After discussing a bit at the office, we decided we don't mind, since we couldn't think of a really problematic scenario with it.

So, we had to change all select queries from

<cfquery name="q" datasource="#mydsn#">
    SELECT col1, col2 FROM mytable
</cfquery>

to

<cftransaction isolation="read_uncommitted">
    <cfquery name="q" datasource="#mydsn#">
        SELECT col1, col2 FROM mytable
    </cfquery>
</cftransaction>

A poor colleague of ours was already given the assignment to do it manually, but lucky for him I came up with the following script, which does it automatically. The only thing the script lacks, is indenting the cfquery one more level.

<cfset dir = "/developing/mysite/" />
<cfdirectory name="q" action="list" directory="#dir#" recurse="yes" filter="*.cfm|*.cfc" />
<cfloop query="q">
	<cfset file = "#q.directory#/#q.name#" />
	<cfoutput>#file#<br /></cfoutput>
	<cfset data = fileread(file) />
	<cfset newdata = rereplaceNoCase(data
		, "([\r\n]{1,2}[\t ]*)(<cfquery [^>]+>[\r\n\t ]*SELECT.*?</cfquery>)"
		, "\1<cftransaction isolation=""read_uncommitted"">\1\2\1</cftransaction>"
		, "all") />
	<cfif data neq newdata>
		<cfset filewrite(file, newdata) />
	</cfif>
</cfloop>
done.

The script recursively scans a directory for cfm and cfc files, and then adds the cftransaction tag around any cfquery which begins with the word "select". Hope it helps you out :-)

Btw: if you were already using cftransactions in your code which includes one or more select queries, then make sure that you are running Railo 3.2.0.004 or later, since support for nested transactions was added then. Adobe Coldfusion also supports nested transactions since version 9.